账号更名脚本

脚本：
---------------------------------------------------------------------------

(@@inputstring)

[@main]
#IF
#say
变更角色名条件：\
1、对于人物，行会成员需要先退出行会；需要回收英雄。\
2、对于英雄，需要召唤出英雄。\
<更换我的角色名/@@InputString5> <更换英雄的名字/@@InputString6>\ \
<关闭/@exit>

[@@InPutString5]
#if
haveGuild
#say
失败，行会成员不能变更角色名！\ \
<关闭/@exit>
#act
sendmsg 0 行会成员不能变更角色名！
break

#if
haveHero
checkHeroOnline
#say
失败，英雄需下线才能更名！\ \
<关闭/@exit>
#act
sendmsg 0 英雄需下线才能更名！
break

#if
#act
changeCharName <$STR(S5)>

[@@InPutString6]
#if
!haveHero
#act
sendmsg 0 你还没有英雄！
break

#if
!checkHeroOnline
#act
sendmsg 0 失败，英雄在线才能更名！
break

#if
#act
h.changeCharName <$STR(S6)>

; 下面为改名结果调用，<$PARAMSTR(0)>:“[英雄] ”，如果非英雄改名则为空
[@chgname_success]
#IF
COMPVAL <$PARAMSTR(0)> =
#act
;在这里<$PARAMSTR(1)>:原角色名，<$PARAMSTR(2)>:新角色名
;执行一些包含了角色名文本的重命名操作...（可以使用StringsReplace和INI_RENAME_SECTION命令来操作）
StringsReplace ..\QuestDiary\rename.txt <$PARAMSTR(1)> <$PARAMSTR(2)> 0 HardDisk
sendmsg 0 人物
#elseACT
sendmsg 0 英雄

[@chgname_fail_name_used]
#say
<$PARAMSTR(0)>失败，新角色名已被使用！\ \
<关闭/@exit>

[@chgname_fail_name_wrong_format]
#say
<$PARAMSTR(0)>失败，新角色名包含了过滤字符！\ \
<关闭/@exit>

[@chgname_fail_no_character]
#say
<$PARAMSTR(0)>失败，查询不到角色！\ \
<关闭/@exit>

[@chgname_fail_incomplete_data]
#say
<$PARAMSTR(0)>失败，数据错误！\ \
<关闭/@exit>

[@chgname_fail_unknow]
#say
<$PARAMSTR(0)>失败，未知错误！\ \
<关闭/@exit>

[@IsInFilterList]
#say
失败，输入文字中包含了过滤字符！\ \
<关闭/@exit>

[@chgname_fail_wrong_format]
#say
失败，输入文字中包含了过滤字符！\ \
<关闭/@exit>