新增NPC标签跳转支持参数：<测试/@测试(1,2,3,4,5,6,7,8,9,10)>

功能说明:
@测试(1,2,3,4,5,6,7,8,9,10) 括号里面的代表参数，最多支持10个参数，以小逗号隔开

新增命令：ESPCHECKSCRIPTPARAM 参数1
功能说明:用于检测参数是否正常，防止非法封包刷数据，参数1是标签中括号里面的内容

新增变量：<$ESPSCRIPTPARAM1>--<$ESPSCRIPTPARAM10>
功能说明:
@测试(1,2,3,4,5,6,7,8,9,10)括号里面的内容分别对应<$ESPSCRIPTPARAM1>--<$ESPSCRIPTPARAM10>
在点击标签后:<$ESPSCRIPTPARAM1>变量内容为1，<$ESPSCRIPTPARAM2>变量为2，以此类推<$ESPSCRIPTPARAM10>变量为10，支持中文

例：
<测试1/@测试(2000,3000,4000,麻痹戒指,5,6,7,8,9,10)>\
<测试2/@测试(2000,3000,4000,复活戒指,5,6,7,8,9,10)>\
<测试3/@测试(2000,3000,4000,护身戒指,5,6,7,8,9,10)>\

[@测试]
#or
ESPCHECKSCRIPTPARAM 2000,3000,4000,麻痹戒指,5,6,7,8,9,10
ESPCHECKSCRIPTPARAM 2000,3000,4000,复活戒指,5,6,7,8,9,10
ESPCHECKSCRIPTPARAM 2000,3000,4000,护身戒指,5,6,7,8,9,10
#act
sendmsg 6 <$ESPSCRIPTPARAM1> - <$ESPSCRIPTPARAM2> - <$ESPSCRIPTPARAM3> - <$ESPSCRIPTPARAM4> - <$ESPSCRIPTPARAM5> - <$ESPSCRIPTPARAM6> - <$ESPSCRIPTPARAM7> - <$ESPSCRIPTPARAM8> - <$ESPSCRIPTPARAM9> - <$ESPSCRIPTPARAM10>
break
#elseact
sendmsg 6 非法的参数

例：
[@main]
合成系统：\ \
<合成麻痹戒指/@合成(1000,2000,3000,圣战戒指,麻痹戒指)>\ \
<合成复活戒指/@合成(1000,2000,3000,天尊戒指,复活戒指)>\ \
<合成护身戒指/@合成(1000,2000,3000,天尊戒指,护身戒指)>

[@合成]
#or
;检查参数是否这几组，防止有可能被刷数据
ESPCHECKSCRIPTPARAM 1000,2000,3000,圣战戒指,麻痹戒指
ESPCHECKSCRIPTPARAM 1000,2000,3000,天尊戒指,复活戒指
ESPCHECKSCRIPTPARAM 1000,2000,3000,天尊戒指,护身戒指
#ELSEACT
;有人用抓包工具刷数据并跳过了检测
sendmsg 6 非法的参数
break

#if
CHECKGAMEGOLD > <$ESPSCRIPTPARAM1>
CHECKGAMEDIAMOND > <$ESPSCRIPTPARAM2>
CHECKGAMEGIRD > <$ESPSCRIPTPARAM3>
checkitem <$ESPSCRIPTPARAM4> 2
#act
Gamegold - <$ESPSCRIPTPARAM1>
GAMEDIAMOND - <$ESPSCRIPTPARAM2>
GAMEGIRD - <$ESPSCRIPTPARAM3>
take <$ESPSCRIPTPARAM4> 2
Give <$ESPSCRIPTPARAM5> 1
sendmsg 6 恭喜合成<$ESPSCRIPTPARAM5>成功。
break
#elsesay
合成<$ESPSCRIPTPARAM5>失败。\
合成<$ESPSCRIPTPARAM5>需要：\
元宝:[<$ESPSCRIPTPARAM1>]，金刚石:[<$ESPSCRIPTPARAM2>]，灵符:[<$ESPSCRIPTPARAM3>]，[<$ESPSCRIPTPARAM4>]:2个。